home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 26 / AACD 26.iso / AACD / Programming / ace_gpl_release / src / lib / startup / startup.s < prev   
Encoding:
Text File  |  1998-10-04  |  11.7 KB  |  619 lines
  1. ;
  2. ; startup.lib (linked library)
  3. ;
  4. ; startup and library management code for all ACE programs.
  5. ; Copyright (C) 1998 David Benn
  6. ; 
  7. ; This program is free software; you can redistribute it and/or
  8. ; modify it under the terms of the GNU General Public License
  9. ; as published by the Free Software Foundation; either version 2
  10. ; of the License, or (at your option) any later version.
  11. ;
  12. ; This program is distributed in the hope that it will be useful,
  13. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15. ; GNU General Public License for more details.
  16. ;
  17. ; You should have received a copy of the GNU General Public License
  18. ; along with this program; if not, write to the Free Software
  19. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  20. ;
  21. ; Author: David J Benn
  22. ;   Date: 3rd,17th,24th,28th,30th November 1991,
  23. ;      27th January 1992, 
  24. ;       2nd,4th,11th,14th-16th,29th February 1992,
  25. ;      1st March 1992,
  26. ;      26th April 1992,
  27. ;      1st,2nd,11th,12th,15th May 1992,
  28. ;      6th,7th,11th,28th,30th June 1992,
  29. ;      4th,7th,16th July 1992
  30. ;      5th,7th,8th,22nd December 1992,
  31. ;      6th,11th,28th February 1993,
  32. ;      1st March 1993,
  33. ;      6th June 1993,
  34. ;      9th,25th October 1993,
  35. ;      27th December 1993,
  36. ;      5th November 1995
  37. ;
  38. ; - Some routines in startup.lib open the shared libaries required by 
  39. ;   an ACE program along with retrieving DOS and Intuition data.
  40. ; - startup.lib also contains startup code for Workbench and Shell launched
  41. ;   programs.
  42. ; - If a library can't be opened or data can't be accessed, _starterr is set
  43. ;   to 1 so that upon return to the main ACE program an abort branch can be 
  44. ;   executed.
  45. ; - If _stdin or _stdout are zero, a WorkBench start is assumed.
  46. ;
  47.  
  48. ; * CONSTANTS *
  49. pr_CLI         equ     172
  50. pr_MsgPort     equ     92
  51. sm_ArgList    equ    36
  52. wa_Lock        equ    0
  53.  
  54.     ; * XDEFs *
  55.     xdef    _DOSBase
  56.     xdef    _MathBase
  57.         xdef    _MathTransBase
  58.         xdef    _MathIeeeSingTransBase
  59.     xdef    _GfxBase
  60.     xdef    _IntuitionBase
  61.     xdef    _TransBase
  62.     xdef    _SysBase
  63.  
  64.     xdef    _RPort
  65.     xdef    _Wdw
  66.     xdef    _Scrn
  67.     xdef    _ViewPort
  68.     xdef    _Wdw_width
  69.     xdef    _Wdw_height
  70.     xdef    _Wdw_id
  71.     xdef    _WBWdw
  72.     xdef    _WBRPort
  73.     xdef    _WBViewPort
  74.     xdef    _WBScrn
  75.     xdef    _WBbgpen
  76.     xdef    _WBfgdpen
  77.     xdef    _IntuiMode
  78.  
  79.     xdef    _returncode
  80.  
  81.     xdef    _cursorON
  82.     xdef    _cursorOFF
  83.     xdef    _turncursoron
  84.     xdef    _turncursoroff
  85.  
  86.     xdef    _cmdlen
  87.     xdef    _cmdbuf
  88.     xdef    _WBenchMsg
  89.     xdef    _TaskAddress
  90.     xdef    _startup
  91.     xdef    _cleanup
  92.     xdef    _starterr
  93.     xdef    _stdout
  94.     xdef    _stdin
  95.     xdef    _openio
  96.     xdef    _closeio
  97.     xdef    _openmathffp
  98.     xdef    _closemathffp
  99.     xdef    _openmathtrans
  100.     xdef    _closemathtrans
  101.     xdef    _opengfx
  102.     xdef    _closegfx
  103.     xdef    _openintuition
  104.     xdef    _closeintuition
  105.     xdef    _opentranslator
  106.     xdef    _closetranslator
  107.     xdef    _fgdpen
  108.     xdef    _bgpen
  109.  
  110.     ; * XREFs needed by startup.lib *
  111.     xref    _AbsExecBase
  112.     xref    _LVOOpenLibrary
  113.     xref    _LVOCloseLibrary
  114.     xref    _LVOFindTask
  115.     xref    _LVOWaitPort
  116.     xref    _LVOGetMsg
  117.     xref    _LVOReplyMsg
  118.     xref    _LVOForbid
  119.     xref    _LVOFreeMem
  120.  
  121.     xref    _LVOOutput
  122.     xref    _LVOInput
  123.            xref    _LVOWrite
  124.     xref    _LVOCurrentDir
  125.  
  126.     xref    _RPort_list
  127.     xref    _Wdw_list
  128.     xref    _Wdw_width_list
  129.     xref    _Wdw_height_list
  130.     xref    _stdout_list
  131.     xref    _stdin_list
  132.     xref    _fgdpen_list
  133.     xref    _bgpen_list
  134.     xref    _storewindowinfo
  135.     xref    _tg_degs
  136.     xref    _tg_tx
  137.     xref    _tg_ty
  138.     xref    _tg_initx
  139.     xref    _tg_inity
  140.     xref    _tg_pen
  141.     xref    _LVOMove
  142.     xref    _turncursoron
  143.     xref    _turncursoroff
  144.  
  145.     xref    _argbuf
  146.  
  147.     xref    _initialise_waveform_data
  148.     xref    _waveformaddr0
  149.     xref    _waveformaddr1
  150.     xref    _waveformaddr2
  151.     xref    _waveformaddr3
  152.     xref    _wavelen0
  153.     xref    _wavelen1
  154.     xref    _wavelen2
  155.     xref    _wavelen3
  156.     xref    _sinwavedata
  157.  
  158. ;
  159. ; opens the DOS library, gets stdio handles & sets up default sound waveform.
  160. ;
  161. _openio:
  162.     move.b    #0,_starterr
  163.             
  164.     ; open DOS library
  165.     movea.l    #_doslib,a1
  166.     move.l    #0,d0            ; version = don't care
  167.     movea.l _AbsExecBase,a6
  168.     jsr    _LVOOpenLibrary(a6)
  169.     move.l    d0,_DOSBase
  170.     cmpi.l    #0,d0
  171.     bne.s    _openio_ok
  172.     move.b    #1,_starterr        ; error
  173.     rts
  174.  
  175. _openio_ok:    
  176.     ; get _stdout handle
  177.     move.l    _DOSBase,a6        
  178.     jsr    _LVOOutput(a6)
  179.     move.l    d0,_stdout
  180.     
  181.     ; get _stdin handle
  182.     move.l    _DOSBase,a6
  183.     jsr    _LVOInput(a6)
  184.     move.l    d0,_stdin
  185.     
  186. _stdin_ok:
  187.       cmpi.l    #0,d0
  188.     beq.s    _soundsetup        ; no I/O handles, no cursor changes!
  189.  
  190.     jsr    _turncursoroff
  191.      
  192. _soundsetup:
  193.         ; set up default waveform data for SOUND statement.
  194.     jsr    _initialise_waveform_data
  195.         
  196. _quitopenio:
  197.     rts
  198.  
  199. ;
  200. ; closes DOS library.
  201. ;
  202. _closeio:
  203.     tst.l    _DOSBase
  204.     beq.s    _quitcloseio
  205.     
  206.     move.l    _DOSBase,a1
  207.     movea.l    _AbsExecBase,a6
  208.     jsr    _LVOCloseLibrary(a6)
  209.  
  210.     cmpi.l    #0,_stdout
  211.     beq.s    _quitcloseio        ; don't turn cursor on if no stdout!
  212.     
  213.     jsr    _turncursoron
  214.  
  215. _quitcloseio:
  216.     rts
  217.  
  218. ;
  219. ; opens Motorola Fast-Floating-Point (FFP) math library.
  220. ;
  221. _openmathffp:
  222.     move.b    #0,_starterr
  223.  
  224.     movea.l #_mathffplib,a1
  225.     move.l  #0,d0
  226.     movea.l _AbsExecBase,a6
  227.     jsr     _LVOOpenLibrary(a6)
  228.     move.l  d0,_MathBase
  229.     cmpi.l    #0,d0
  230.     bne.s    _mathffp_ok
  231.     move.b    #1,_starterr
  232.  
  233. _mathffp_ok:
  234.         rts
  235.  
  236. ;
  237. ; closes FFP library.
  238. ;
  239. _closemathffp:
  240.     tst.l    _MathBase
  241.     beq.s    _quitclosemathffp
  242.  
  243.     move.l  _MathBase,a1
  244.     movea.l _AbsExecBase,a6
  245.     jsr     _LVOCloseLibrary(a6)
  246.  
  247. _quitclosemathffp:
  248.     rts
  249.        
  250. ;
  251. ; opens FFP and IEEE transendental function libraries.
  252. ;
  253. _openmathtrans:
  254.     move.b    #0,_starterr
  255.     
  256.     movea.l #_mathtranslib,a1
  257.     move.l  #0,d0
  258.     movea.l _AbsExecBase,a6
  259.     jsr     _LVOOpenLibrary(a6)
  260.     move.l  d0,_MathTransBase
  261.     cmpi.l    #0,d0
  262.     bne.s    _openieeesingtranslib
  263.     move.b    #1,_starterr
  264.     rts            ; if we can't open FFP library -> abort!
  265.  
  266. _openieeesingtranslib:
  267.     ;
  268.     ; IEEE SP Transcendental library is currently only
  269.     ; used by the _power function. If it can't be opened,
  270.     ; FFP exponentiation function is used instead, so don't
  271.     ; set _starterr if we can't open mathieeesingtrans.library.
  272.     ; See ACE/src/lib/c/pow.c for more details.
  273.     ; 
  274.     movea.l #_mathieeesingtranslib,a1
  275.     move.l  #0,d0
  276.     movea.l _AbsExecBase,a6
  277.     jsr     _LVOOpenLibrary(a6)
  278.     move.l  d0,_MathIeeeSingTransBase    
  279.  
  280.         rts
  281.  
  282. ;
  283. ; close FFP transendental function library.
  284. ;
  285. _closemathtrans:
  286.     tst.l    _MathTransBase
  287.     beq.s    _quitclosemathtrans
  288.  
  289.     move.l  _MathTransBase,a1
  290.     movea.l _AbsExecBase,a6
  291.     jsr     _LVOCloseLibrary(a6)
  292.  
  293. _quitclosemathtrans:
  294.     rts
  295.  
  296. ;
  297. ; open intuition library and get standard rastport.
  298. ;
  299. _openintuition:
  300.     move.b    #0,_starterr
  301.  
  302.     ; open library
  303.     movea.l    #_intuitionlib,a1
  304.     move.l    #0,d0
  305.     movea.l    _AbsExecBase,a6
  306.     jsr    _LVOOpenLibrary(a6)
  307.     move.l    d0,_IntuitionBase
  308.     cmpi.l    #0,d0
  309.     bne.s    _intuition_ok
  310.     move.b    #1,_starterr        ; error
  311.     rts
  312.  
  313. _intuition_ok:
  314.     ; get window, rastport
  315.     ; and viewport
  316.     movea.l    d0,a1
  317.     movea.l    52(a1),a1        ; ActiveWindow 
  318.     move.l    a1,_Wdw
  319.     cmpa.l    #0,a1
  320.     bne.s    _Wdw_ok
  321.     move.b    #1,_starterr        ; error (no startup window -> shell/cli)
  322.     rts
  323.  
  324. _Wdw_ok:
  325.     move.l    50(a1),_RPort        ; Rastport of ActiveWindow
  326.     
  327.     ; approx. size of window (Wb 2.04 shell)
  328.     move.w    #640,_Wdw_width
  329.     move.w    #100,_Wdw_height
  330.  
  331.     ; get Wb screen
  332.     movea.l    _IntuitionBase,a1
  333.     movea.l    56(a1),a1        
  334.     move.l    a1,_Scrn        ; ActiveScreen
  335.     move.l    a1,d0
  336.     add.l    #44,d0
  337.     move.l    d0,_ViewPort        ; ViewPort is 44 bytes 
  338.                     ; from start of screen structure.
  339.  
  340.     ; store Wb globals
  341.     move.l    _RPort,_WBRPort
  342.     move.l    _ViewPort,_WBViewPort
  343.     move.l    _Scrn,_WBScrn
  344.     move.l    _Wdw,_WBWdw
  345.     move.b    #0,_IntuiMode
  346.  
  347.     ; number of Wb window (shell/cli)
  348.     move.w    #0,_Wdw_id
  349.  
  350.     move.w    #1,_fgdpen        ; current drawing pen color
  351.     move.w    #0,_bgpen        ; current background pen color
  352.     move.w    #1,_WBfgdpen        
  353.     move.w    #0,_WBbgpen        
  354.  
  355.     ; in case _heading ONLY is 
  356.     ; called without any TG stuff!
  357.  
  358.     move.w    #270,_tg_degs        ; initial heading is 270 degs (north)
  359.  
  360.     rts
  361.  
  362. ;
  363. ; close intuition library.
  364. ;
  365. _closeintuition:
  366.     tst.l    _IntuitionBase
  367.     beq.s    _quitcloseintuition
  368.  
  369.     move.l  _IntuitionBase,a1
  370.     movea.l _AbsExecBase,a6
  371.     jsr     _LVOCloseLibrary(a6)
  372.  
  373. _quitcloseintuition:
  374.     rts
  375.  
  376. ;
  377. ; open graphics library.
  378. ;
  379. _opengfx:
  380.     move.b    #0,_starterr
  381.  
  382.     ; open library
  383.     movea.l    #_gfxlib,a1
  384.     move.l    #0,d0
  385.     movea.l    _AbsExecBase,a6
  386.     jsr    _LVOOpenLibrary(a6)
  387.     move.l    d0,_GfxBase
  388.     cmpi.l    #0,d0
  389.     bne.s    _gfx_ok
  390.     move.b    #1,_starterr        ; error
  391.  
  392. _gfx_ok:
  393.     ; initialise turtle graphics 
  394.     move.w    #270,_tg_degs        ; initial heading is 270 degs (north)
  395.     move.w    _tg_initx,_tg_tx    ; initial x coordinate
  396.     move.w    _tg_inity,_tg_ty    ; initial y coordinate
  397.     move.l    _GfxBase,a6
  398.     move.l    _RPort,a1
  399.     move.w    _tg_tx,d0
  400.     move.w    _tg_ty,d1
  401.     jsr    _LVOMove(a6)        ; move to home position 
  402.     move.b    #1,_tg_pen        ; pen is initially down
  403.  
  404.     rts
  405.  
  406. ;
  407. ; close graphics library.
  408. ;
  409. _closegfx:
  410.     tst.l    _GfxBase
  411.     beq.s    _quitclosegfx
  412.  
  413.     move.l  _GfxBase,a1
  414.     movea.l _AbsExecBase,a6
  415.     jsr     _LVOCloseLibrary(a6)
  416.  
  417. _quitclosegfx:
  418.     rts
  419.  
  420. ;
  421. ; open translator library
  422. ;
  423. _opentranslator:
  424.     move.b    #0,_starterr
  425.  
  426.     movea.l    #_translatorlib,a1
  427.     move.l    #0,d0
  428.     movea.l    _AbsExecBase,a6
  429.     jsr    _LVOOpenLibrary(a6)
  430.     move.l    d0,_TransBase
  431.     cmpi.l    #0,d0
  432.     bne.s    _translator_ok
  433.     move.b    #1,_starterr        ; error
  434.  
  435. _translator_ok:
  436.     rts
  437.  
  438. ;
  439. ; close translator library
  440. ;
  441. _closetranslator:
  442.     tst.l    _TransBase
  443.     beq.s    _quitclosetranslator
  444.     
  445.     move.l  _TransBase,a1
  446.     movea.l _AbsExecBase,a6
  447.     jsr     _LVOCloseLibrary(a6)
  448.  
  449. _quitclosetranslator:
  450.     rts
  451.  
  452. ;
  453. ; Startup code for all ACE programs. 
  454. ;
  455. _startup:
  456.     ; save d0 & a0 in case CLI
  457.     ; arg's required.
  458.     move.l    d0,_cmdlen
  459.     move.l    a0,_cmdbuf
  460.  
  461.     ; make _SysBase available to ami.lib
  462.     move.l    _AbsExecBase,_SysBase
  463.  
  464.     ; open dos.library
  465.     jsr    _openio
  466.     tst.l    _DOSBase
  467.     beq.s    _quitstartup    ; _starterr will be set to 1
  468.  
  469.     ; get task's address
  470.     movea.l    _AbsExecBase,a6
  471.     suba.l    a1,a1
  472.     jsr    _LVOFindTask(a6)
  473.     move.l    d0,_TaskAddress
  474.     
  475.     ; look at Process structure
  476.     ; to determine whether
  477.     ; process started from Wb
  478.     movea.l    d0,a4
  479.     tst.l    pr_CLI(a4)        
  480.     beq.s    _fromWb
  481.     move.l    #0,_WBenchMsg     ; no message
  482.     rts             ; Not started from Wb
  483.  
  484. _fromWb:
  485.     ; wait for Wb message
  486.     movea.l    _AbsExecBase,a6
  487.     lea    pr_MsgPort(a4),a0
  488.     jsr    _LVOWaitPort(a6) ; wait for msg
  489.     lea    pr_MsgPort(a4),a0
  490.     jsr    _LVOGetMsg(a6)     ; get msg
  491.     move.l    d0,_WBenchMsg     ; store msg    
  492.  
  493.     ; make current directory
  494.     ; the working directory.
  495.     movea.l    d0,a2
  496.     move.l    sm_ArgList(a2),d0
  497.     beq.s    _quitstartup
  498.     movea.l    _DOSBase,a6
  499.     movea.l    d0,a0
  500.     move.l    wa_Lock(a0),d1        
  501.     jsr    _LVOCurrentDir(a6)
  502.     
  503. _quitstartup:
  504.     rts    
  505.  
  506. ;
  507. ; Cleanup code for all ACE programs.
  508. ;
  509. _cleanup:
  510.     ; free allocated argument buffer. 
  511.     tst.l    _argbuf
  512.     beq.s    _closedos    ; if no memory allocated -> skip freemem
  513.     movea.l    _AbsExecBase,a6
  514.     movea.l    _argbuf,a1    ; buffer address
  515.     move.l    _cmdlen,d0    ; # of bytes allocated (see arg.c)
  516.     jsr    _LVOFreeMem(a6)
  517.     
  518. _closedos:
  519.     ; close dos.library
  520.     jsr    _closeio    
  521.  
  522.     ; if there is a Wb message, reply to it.
  523.     tst.l    _WBenchMsg
  524.     bne.s    _replytoWBMsg    
  525.  
  526.     ; otherwise just exit with return code (CLI/shell start).
  527.     move.l    _returncode,d0
  528.     rts
  529.  
  530. _replytoWBMsg:
  531.     ; exit from a Wb launched program. 
  532.     move.l    _AbsExecBase,a6
  533.     jsr    _LVOForbid(a6)
  534.     move.l    _WBenchMsg,a1
  535.     jsr    _LVOReplyMsg(a6)
  536.     rts
  537.  
  538. ;
  539. ; turn cursor on.
  540. ;
  541. _turncursoron:
  542.     move.l    _stdout,d1
  543.     move.l    #_cursorON,d2
  544.     moveq    #3,d3
  545.     move.l    _DOSBase,a6
  546.     jsr    _LVOWrite(a6)
  547.     rts
  548.  
  549. ;
  550. ; turn cursor off.
  551. ;
  552. _turncursoroff:
  553.     move.l    _stdout,d1
  554.     move.l    #_cursorOFF,d2
  555.     moveq    #4,d3
  556.     move.l    _DOSBase,a6
  557.     jsr    _LVOWrite(a6)
  558.     rts
  559.  
  560. ;************************
  561.  
  562.     SECTION    startup_data,DATA
  563.  
  564. _version:    dc.b    '$VER: startup 1.12 (05.11.95)',0
  565.  
  566. _doslib:        dc.b    'dos.library',0
  567. _mathffplib:        dc.b    'mathffp.library',0
  568. _mathtranslib:      dc.b    'mathtrans.library',0
  569. _mathieeesingtranslib:     dc.b    'mathieeesingtrans.library',0
  570. _gfxlib:        dc.b    'graphics.library',0
  571. _intuitionlib:        dc.b    'intuition.library',0
  572. _translatorlib:     dc.b    'translator.library',0
  573.  
  574. _IntuiMode:    dc.b     0
  575.  
  576. _returncode:    dc.l    0
  577.  
  578. _cursorOFF:    dc.b    $9b,$30,$20,$70
  579. _cursorON:    dc.b    $9b,$20,$70
  580.  
  581.     SECTION startup_mem,BSS
  582.  
  583. _cmdlen:    ds.l 1
  584. _cmdbuf:    ds.l 1
  585. _starterr:    ds.b 1
  586. _DOSBase:    ds.l 1
  587. _stdout:    ds.l 1
  588. _stdin:        ds.l 1
  589.  
  590. _MathBase:          ds.l 1
  591. _MathTransBase:     ds.l 1
  592. _MathIeeeSingTransBase: ds.l 1
  593. _GfxBase:        ds.l 1
  594. _IntuitionBase:     ds.l 1
  595. _TransBase:        ds.l 1
  596. _SysBase:        ds.l 1
  597.  
  598. _RPort:        ds.l 1
  599. _Wdw:        ds.l 1
  600. _Scrn:        ds.l 1
  601. _ViewPort:    ds.l 1
  602. _Wdw_width:    ds.w 1
  603. _Wdw_height:    ds.w 1
  604. _Wdw_id:    ds.w 1
  605. _WBWdw:        ds.l 1
  606. _WBRPort:    ds.l 1
  607. _WBViewPort:    ds.l 1
  608. _WBScrn:    ds.l 1
  609. _WBbgpen:    ds.w 1
  610. _WBfgdpen:    ds.w 1
  611.  
  612. _fgdpen:    ds.w 1
  613. _bgpen:        ds.w 1
  614.  
  615. _TaskAddress:    ds.l 1
  616. _WBenchMsg:    ds.l 1
  617.  
  618.     END
  619.